Hello everybody!

I have trouble programming dataTaker DT85.

I would like to make a job with 4 different schedules:

First schedule should start every monday at 00:00 til 09:00 am.
It should sample and log data (voltage) every 10 min and put digital outputs 1D and 2D in to a known state.
I had an idea how should it look:

RA10M"UC_pr1"("b:",ALARMS:OV:100KB:W60,DATA:OV:10MB)[:::0-9::1]10M
LOGONA
1DSO=0
DELAY=1000
2DSO=1
1-V("name1~mV",LM,A)
1+V("name2~mV",LM,A)
1*V("name3~mV",LM,A)

Can someone tell me are those right commands (or better what's wrong)?

The second schedule is almost the same just digital states are reversed and schedule should start every monday at 10am (until next schedule).
RB10M"UC_po2"("b:",ALARMS:OV:100KB:W60,DATA:OV:10MB)[:::10::1]10M
LOGONB
2DSO=0
DELAY=1000
1DSO=1
1-V("ime1~mV",LM,A)
1+V("ime2~mV",LM,A)
1*V("ime3~mV",LM,A)

The third one is a bit different.
It must have faster sampling time (10s) and should start every tuesday at 10 am. Digital outputs are reversed again
RC10S"UC_pr3"("b:",ALARMS:OV:100KB:W60,DATA:OV:80MB)[:::10::2]10S
LOGONC
1DSO=0
DELAY=1000
2DSO=1
1-V("ime1~mV",LM,A)
1+V("ime2~mV",LM,A)
1*V("ime3~mV",LM,A)

The last schedule should start on wednesday at 10am and should run until monday 0:00 when schedule 1 should start. Again digital outpust are revesed and sampling and logging are in 10 min intervals.

RD10M"UC_po4"("b:",ALARMS:OV:100KB:W60,DATA:OV:10MB)[:::10::3]10M
LOGOND
2DSO=0
DELAY=1000
1DSO=1
1-V("ime1~mV",LM,A)
1+V("ime2~mV",LM,A)
1*V("ime3~mV",LM,A)

I will be very greatful for any help! If anybody has any different idea how should this be done you are very welcome!
Thank you in advance!

Peter

Hi Peter,

You can't declare time trigger twice and using it with CRON trigger.
RA10M"UC_pr1"("b:",ALARMS:OV:100KB:W60,DATA:OV:10MB)[:::0-9::1]10M

• using * means all values, you will get 1 second interval if you used it on second block
• you can't set hourly CRON on date block

I can give an example with schedule A which fully utilize CRON trigger:
RA"UC_pr1"("b:",ALARMS:OV:100KB:W60,DATA:OV:10MB)[0:/10:0-9::*:1]

The above CRON [0:/10:0-9::*:1] will caused schedule A to run every Monday between 0 - 9 AM and every 10 minutes.

Please elaborate further schedule B and C, what is the stop time?

For schedule D, you may use different approach using schedule J and schedule A

RA"UC_pr1"("b:",ALARMS:OV:100KB:W60,DATA:OV:10MB)[0:/10:0-9:::1]
LOGONA
DO{HD}
1DSO=0
DELAY=1000
2DSO=1
1-V("name1~mV",LM,A)
1+V("name2~mV",LM,A)
1V("name3~mV",LM,A)

RD"UC_po4"("b:",ALARMS:OV:100KB:W60,DATA:OV:10MB)10M HD
LOGOND
2DSO=0
DELAY=1000
1DSO=1
1-V("ime1~mV",LM,A)
1+V("ime2~mV",LM,A)
1*V("ime3~mV",LM,A)

RJ1H
IF(3ST==10)AND IF(4ST==3){GD}

Schedule D will be on halt (HD) and schedule J will start it when 3ST equal to 10 (10 AM) and 4ST equal to 3 (Wednesday).
Then schedule A will halt schedule D.

Best regards,
Rudy Gunawan

Rudy Thanks for your help!

At the end I decided to make seperate control and measurement schedules and most of schedules start at midnight of a selected day.

Just for info I post used program inside a given schedule:

RB'UCM1'("a:",ALARMS:OV:100KB:W60,DATA:OV:50MB)[0:/10::::0-2,4,5,6]
LOGONB
1-V("ime1~mV",LM,A)
1+V("ime2~mV",LM,A)
1*V("ime3~mV",LM,A)

RC'UCM2'("a:",ALARMS:OV:100KB:W60,DATA:OV:300MB)[0:::::3]
LOGONC
1-V("ime1~mV",LM,A)
1+V("ime2~mV",LM,A)
1*V("ime3~mV",LM,A)

RD'UCPR1'[0:0:0:::1]
DELAY=1000
1DSO=1
DELAY=1000
2DSO=0

RE'UCPO2'[0:0:0:::2]
DELAY=1000
2DSO=1
DELAY=1000
1DSO=0

RF'UCPR3'[0:5:0:::3]
DELAY=1000
1DSO=1
DELAY=1000
2DSO=0

RG'UCPO4'[0:0:0:::4]
DELAY=1000
2DSO=1
DELAY=1000
1DSO=0

I hope this will help somebody like Rudy,s helped me.

Hi Peter,

Thanks for the program, you managed to solve it using another approach.

Best regards,
Rudy Gunawan